org  $bf10 -13

        ld  hl, 23784
        ld  de, velozloader
        ld  b,1
        ldir
        jp  start_loading
     
        org  $bf10

velozloader 
        push  hl
        exx
        pop  de
        ex   de , hl  
        ld   b, (hl)
        inc  hl
        ld   c, (hl)
        exx

        ld  bc, $0efe
        ld  de, $10ea

pii     xor a
        out (c),e

pi_LOW  inc a
        in  f,(c)
        jp  po, pi_LOW

        out (c),b

pi_HIGH inc a
        in  f,(c)
        jp  pe, pi_HIGH

SYNC    cp  50   
        rl  d
        cp  40   
        jr  nc, pii

        inc d
        jr  nz , pii

syn_LOW in  f,(c)
        jp  po, syn_LOW

        cp  17      
        ld  a,e ; $ea

        jr  c, no_inv

        xor 8

syn_hi  in  f,(c)
        jp  pe, syn_hi
no_inv
        ld  (pe1),a
        xor 8
        ld  (po1),a

        ld  ixl,d

        ex  de,hl

        ld  b,11
        xor a
        jr  enter
table
       defb $fc,$fc
       defb $fc,$fc,$fc,$fc,$fc
       defb $fd,$fd,$fd,$fd,$fd
       defb $fe,$fe,$fe,$fe,$fe
       defb $ff,$ff,$ff,$ff,$ff
       defb $ff,$ff,$ff
       defb $40,$40,$40,$40,$40

full    and  H
        ld   (de),a
        inc  de
        xor  ixl
        ld   ixl,a
        ld   a, c;      

enter
more
HIGH    inc  hl
        in  f , (c)
pe1     jp  pe , HIGH

        ld h,$bf
        ld h,(hl)

        ld l,(table-$bf00)- 5

        rlca
        rla               

LOW     inc  hl
        in  f,(c)
po1     jp  po, LOW      

        jp  nC, full

        dec  b
        set  3,b
        out (c),b
        and  H
        jp  m, more  
    
        
        exx
        ld   (hl),c
        dec  hl
        ld   (hl),b
        ex   de , hl  
        exx

        ld a,ixl
        or  a
        ret


start_loading       

        nop