dir_HAIGH        equ      &80
       
        org  dir_HAIGH*&100 +  &10

 
        jp startloader
          

velozloader   ;equ $8013
pilot
        push hl
        exx
        pop  hl  
        ld   d, (hl)
        inc  hl
        ld   e, (hl)

        ld    bc , $7f10
        out   (c),c         ;border
        ld    c , $44
        exx
    
        ld   bc, &f5fe  ;
        ld   d,  &10
 
 
pii     
        exx  
        ld   a,$4a
        out  (c),a  ;
        exx

        xor  a
         
pi_LOW  inc  a
        in   f,(c)
        jp   m, pi_LOW

        exx  
        out  (c),c  
        exx

pi_HIGH inc  a
        in   f,(c)
        jp   p , pi_HIGH


        cp   47    
        rl   d
        cp   33   
        jr   nc, pii

        inc  d
        jr   nz , pii
 
syn_LOW in   f,(c)
        jp   m, syn_LOW

        cp   17       
        ld   a, $f2     ;e ; $fa 

        jr   c, no_inv

        xor  8

syn_hi  in   f,(c)
        jp   p , syn_hi

no_inv
        ld   (p1),a
        xor  8
        ld   (m1),a

        ld   ixl,d

        ex   de,hl

        xor  a
        jr   enter
table
       defb  &fc,&fc
       defb  &fc,&fc,&fc,&fc,&fc
       defb  &fd,&fd,&fd,&fd,&fd
       defb  &fe,&fe,&fe,&fe,&fe
       defb  &ff,&ff,&ff,&ff,&ff
       defb  &ff,&ff,&ff
       defb  &40,&40,&40,&40,&40
       defb  &40,&40,&40

full    and  H
        ld   (de),a
        inc  de
        xor  ixl
        ld   ixl,a
        ld   a,   c;      ;  10 + 37  =  47

enter
more    
HIGH    inc  hl
        in   f , (c)
p1      jp   p , HIGH

        exx
        res  4,c
        exx
        
        ld   h, dir_HAIGH  ;&80
        ld   h, (hl)

        ld   l, table - (dir_HAIGH  * &100) -4;  &64

        rlca
        rla                ; 16 + 21 +8 =  45

LOW     inc  hl
        in   f,(c)
m1      jp   m, LOW      

        jp   nC, full


        exx
        out  (c),c
        inc  c
        exx

        and  H
        jp   m, more   ; 10 + 24 + 4+ 10 = 48
                           
  
        exx
        ld   (hl),e
        dec  hl
        ld   (hl),d 
        exx

        ld   a,ixl
        or   a
        ret

startloader

        nop
       

        di

        ld  sp, velozloader -4                

        ld hl, $bffe             ; pagina 3  (pantalla)
        call velozloader                 

        ld hl, $fffe     ; pagina 0
        call velozloader                 

        ld hl, $3ffe     ; pagina 1
        call velozloader                 

        ld hl, $80fe     ; pagina 2
        call velozloader                 

        ld a, $c4  ; pagina 0*
        call next_page

        ld a, $c5  ; pagina 1*
        call next_page

        ld a, $c6  ; pagina 2*
        call next_page

        ld a, $c7  ; pagina 3*
        call next_page
                                                 
        jp $c91d        ; restaura snapshot              

next_page: 

        ld b, $7f     ;OUT &7Fxx, ; %11bbbmmm   ;   actualizar ram mode 
        out (c), a                      
        ld  hl,$3ffe             
        jp  velozloader                   
        nop